home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / Emulatoren / zxam20.lha / ZXAM Spectrum / ZXAM_Rexx / Español / SaveScreen.zxam < prev    next >
Encoding:
Text File  |  1994-10-22  |  4.0 KB  |  112 lines
  1. /* este script graba la pantalla del spectrum como IFF sin compresión */
  2.     
  3.     address command
  4.     
  5.     if ~show(ports,ZXAM_REXX) then do
  6.         requestchoice 'title "ZXAM Script error..." body "No encuentro el puerto del emulador!!" gadgets "AARGH!"'
  7.         exit 0
  8.         end
  9.  
  10. /* Usamos el requester del emulador para pedir nombre del fichero */
  11.     
  12.     cajon=""  /* aqui puedes meter el path que uses para pantallas */
  13.     
  14.     oldcajon=zxamactloadpath()    /* guardamos el path del requester */
  15.     oldpattern=zxamactpattern()    /* guardamos el pattern del requester */
  16.     zxampattern('(#?.iff|#?.pic)')  /* filtro para mostrar solo pantallas */
  17.     
  18.     nombre=zxamsaverequester('Nombre para grabar el IFF...',cajon)
  19.     
  20.     zxampattern(oldpattern)        /* recuperamos el pattern */
  21.     zxamloadpath(oldcajon)        /* recuperamos el path */    
  22.     
  23.     if nombre='' then do
  24.         exit    /* selección cancelada */
  25.         end
  26.     
  27. /* Abrimos el fichero */
  28.  
  29.     if ~OPEN('fichero',nombre,'Write') then exit 0
  30.     
  31.     oldname=zxamactname()        /* guardamos nombre y formato */
  32.     oldformat=zxamactformat()
  33.     
  34.     zxamnameformat('    (GRABANDO PANTALLA IFF)','')
  35.     
  36. /* cabecera identificadora. indica tamaño TODO menos 'FORM' */
  37.     dummy=writech('fichero','FORM')
  38.     dummy=writech('fichero','000060a8'x)    /* tamaño total */
  39.     dummy=writech('fichero','ILBM')
  40.  
  41. /* chunk ANNO */
  42.     dummy=writech('fichero','ANNO')
  43.     dummy=writech('fichero','00000033'x)    /* tamaño 51 caracteres */
  44.     dummy=writech('fichero','Saved by ZXAM Spectrum Emulator AGA (by Toni Pomar)')
  45.     dummy=writech('fichero','00'x)        /* pad para alinear */
  46.  
  47. /* chunk BMHD, o sea, bloque indicador de tamaño página */
  48.     dummy=writech('fichero','BMHD')
  49.     dummy=writech('fichero','00000014'x)    /* tamaño 20 */
  50.     dummy=writech('fichero','0100'x)    /* ancho */
  51.     dummy=writech('fichero','00c0'x)    /* alto */
  52.     dummy=writech('fichero','0000'x)    /* pos x */
  53.     dummy=writech('fichero','0000'x)    /* pos y */
  54.     dummy=writech('fichero','04'x)        /* nro bitplanos */
  55.     dummy=writech('fichero','00'x)        /* masking */
  56.     dummy=writech('fichero','00'x)        /* compression */
  57.     dummy=writech('fichero','00'x)        /* Pad1 */
  58.     dummy=writech('fichero','0000'x)    /* color transparente */
  59.     dummy=writech('fichero','2c2c'x)    /* aspect 44:44 */
  60.     dummy=writech('fichero','0140'x)    /* ancho página fuente (320) */
  61.     dummy=writech('fichero','0100'x)    /* alto página fuente (256) */
  62.  
  63. /* chunk CAMG, o sea, modo de pantalla (PAL:Baja resolución) */
  64.     dummy=writech('fichero','CAMG')
  65.     dummy=writech('fichero','00000004'x)    /* tamaño 4 */
  66.     dummy=writech('fichero','00000000'x)    /* 00021000 = PAL:Baja resolución */
  67.  
  68. /* chunk CMAP, o sea, mapa de colores */
  69.  
  70.     dummy=writech('fichero','CMAP')
  71.     dummy=writech('fichero','00000030'x)    /* tamaño 48 (16 colores*3 bytes) */
  72.     
  73.     /* color del borde */
  74.     /* El color (0 a 7) es el índice para la tabla de colores */
  75.     /* que creamos en forma de cadena MUY larga */
  76.     dummy=writech('fichero',x2c(substr('000000000099990000990099009900009999999900999999',(zxamgetreg(bor)*6)+1,6)))
  77.     
  78.     dummy=writech('fichero','000099'x)    /* color 1 */
  79.     dummy=writech('fichero','990000'x)    /* color 2 */
  80.     dummy=writech('fichero','990099'x)    /* color 3 */
  81.     dummy=writech('fichero','009900'x)    /* color 4 */
  82.     dummy=writech('fichero','009999'x)    /* color 5 */
  83.     dummy=writech('fichero','999900'x)    /* color 6 */
  84.     dummy=writech('fichero','999999'x)    /* color 7 */
  85.     dummy=writech('fichero','000000'x)    /* color 8 */
  86.     dummy=writech('fichero','0000aa'x)    /* color 9 */
  87.     dummy=writech('fichero','bb0000'x)    /* color 10 */
  88.     dummy=writech('fichero','cc00cc'x)    /* color 11 */
  89.     dummy=writech('fichero','00cc00'x)    /* color 12 */
  90.     dummy=writech('fichero','00dddd'x)    /* color 13 */
  91.     dummy=writech('fichero','eeee00'x)    /* color 14 */
  92.     dummy=writech('fichero','ffffff'x)    /* color 15 */
  93.     
  94.  
  95. /* chunk BODY, o sea, bitplanos en formato entrelazado */
  96.  
  97.     dummy=writech('fichero','BODY')
  98.     dummy=writech('fichero','00006000'x)    /* tamaño 6144*4 (4 bpls de 256*192) */
  99.  
  100. /* usamos una funcion especial del emulador para sacar la pantalla en 4 bitplanos */
  101.  
  102.     dummy=writech('fichero',zxamgetscr())
  103.  
  104.     dummy=close('fichero')
  105.     
  106.     if oldname=='' then
  107.         zxamclearnameformat()
  108.     else
  109.         zxamnameformat(oldname,oldformat)
  110.     
  111.     exit
  112.